Emanuele Feronato

Talking about Actionscript 3 and Flash.

This is quite the same tutorial as How to use Google Maps API with Flash AS3, but this time we’ll learn how to use Yahoo! Maps.

As usual, you first have to sign up for the API key at this link.

Then you will be given a code, like the one in this picture:

Then, you must download the component and install it in your Flash environment.

Now you’re ready to start a Yahoo! Maps project.

Include the component in your stage and check out this source code:

package {
	// libraries used by yahoo maps
	import com.yahoo.maps.api.YahooMap;
	import com.yahoo.maps.api.YahooMapEvent;
	import com.yahoo.maps.api.core.location.LatLon;
	import flash.display.Sprite;
	public class yahoomap extends Sprite {
		// creating a Yahoo map object
		public var my_yahoo_map:YahooMap = new YahooMap();
		// keycode
		var key:String="lHsd5HTV34HrkDmmwIa1P4.upNCGCbAUBoYFRaO0jJYAEgG8LV8ZyygbP6w_x.nBmNPRYwr2Jg--";
		public function yahoomap() {
			// adding an event when the map is initialized
			my_yahoo_map.addEventListener(YahooMapEvent.MAP_INITIALIZE, on_map_initialized);
			// defining how the map should be initialized...
			// the parameters represent the keycode and the stage width and hieht
			my_yahoo_map.init(key, stage.stageWidth, stage.stageHeight);
			// adding pan control
			my_yahoo_map.addPanControl();
			// adding zoom control
			my_yahoo_map.addZoomWidget();
			// adding type control (allows you to switch among street, satellite and hybrid)
			my_yahoo_map.addTypeWidget();
			// adds the scale control
			my_yahoo_map.addScaleBar();
			// adding the object on stage
			this.addChild(my_yahoo_map);
		}
		private function on_map_initialized(event:YahooMapEvent):void {
			// setting the zoom level... it ranges from 1 (closest) to 17
			my_yahoo_map.zoomLevel=14;
			// setting the latitude and longitude of the map
			my_yahoo_map.centerLatLon=new LatLon(20.349230,-74.498468);
		}
	}
}

To have a Yahoo! Maps displaying Cuba.

Remember the Yahoo! Maps API is a free service for any application that is free of charge and does not exceed the rate limit of 50,000 requests.

Next time I’ll show you some tricks you can do with both Google and Yahoo! Maps.

Download the source code.