Emanuele Feronato

Talking about Actionscript 3, Box2D and Flash.

After introducing Distance Joints, it’s time to learn something about Revolute Joints.

A Revolute Joint attaches two objects by “pinning” them together at an anchor point which they may revolve around.

The most interesting thing, that I will cover in another post, is the capibility of making motors out of Revolute Joints. Yes… motors… engines… easy to do and ecologic since they don’t need fuel, just some code.

But at the moment let’s see the basic Revolute Joint.

Here it is:

Now let’s see how to make this possible:

package {
	import flash.display.Sprite;
	import flash.events.Event;
	import Box2D.Dynamics.*;
	import Box2D.Collision.*;
	import Box2D.Collision.Shapes.*;
	import Box2D.Common.Math.*;
	import Box2D.Dynamics.Joints.*;
	import flash.events.MouseEvent;
	public class revolute_joint extends Sprite {
		var mouseJoint:b2MouseJoint;
		var mousePVec:b2Vec2 = new b2Vec2();
		var bd:b2BodyDef;
		var the_box:b2PolygonDef = new b2PolygonDef();
		var the_pivot:b2CircleDef = new b2CircleDef();
		var the_rev_joint:b2RevoluteJointDef = new b2RevoluteJointDef();
		public function revolute_joint() {
			// world setup
			var worldAABB:b2AABB = new b2AABB();
			worldAABB.lowerBound.Set(-100.0, -100.0);
			worldAABB.upperBound.Set(100.0, 100.0);
			var gravity:b2Vec2=new b2Vec2(0.0,10.0);
			var doSleep:Boolean=true;
			m_world=new b2World(worldAABB,gravity,doSleep);
			// debug draw
			var m_sprite:Sprite;
			m_sprite = new Sprite();
			addChild(m_sprite);
			var dbgDraw:b2DebugDraw = new b2DebugDraw();
			var dbgSprite:Sprite = new Sprite();
			m_sprite.addChild(dbgSprite);
			dbgDraw.m_sprite=m_sprite;
			dbgDraw.m_drawScale=30;
			dbgDraw.m_alpha = 1;
			dbgDraw.m_fillAlpha=0.5;
			dbgDraw.m_lineThickness=1;
			dbgDraw.m_drawFlags=b2DebugDraw.e_shapeBit|b2DebugDraw.e_jointBit;
			m_world.SetDebugDraw(dbgDraw);
			// pivot for revolute joint
			the_pivot.radius = 0.5;
			the_pivot.density = 0;
			bd = new b2BodyDef();
			bd.position.Set(8.5,6.5);
			var rev_joint:b2Body = m_world.CreateBody(bd);
			rev_joint.CreateShape(the_pivot)
			rev_joint.SetMassFromShapes();
			// box for the revolute joint
			the_box.SetAsBox(4,0.5);
			the_box.density = 0.01;
			the_box.friction = 1;
			the_box.restitution = 0.1;
			bd = new b2BodyDef();
			bd.position.Set(6.5,6.5);
			var rev_box:b2Body = m_world.CreateBody(bd);
			rev_box.CreateShape(the_box)
			rev_box.SetMassFromShapes();
			the_rev_joint.Initialize(rev_joint, rev_box, new b2Vec2(8.5,6.5));
			var joint_added:b2RevoluteJoint = m_world.CreateJoint(the_rev_joint) as b2RevoluteJoint;
			// listeners
			stage.addEventListener(MouseEvent.MOUSE_DOWN, createMouse);
			stage.addEventListener(MouseEvent.MOUSE_UP, destroyMouse);
			addEventListener(Event.ENTER_FRAME, Update, false, 0, true);
		}
		public function createMouse(evt:MouseEvent):void {
			var body:b2Body=GetBodyAtMouse();
			if (body) {
				var mouseJointDef:b2MouseJointDef=new b2MouseJointDef;
				mouseJointDef.body1=m_world.GetGroundBody();
				mouseJointDef.body2=body;
				mouseJointDef.target.Set(mouseX/30, mouseY/30);
				mouseJointDef.maxForce=30000;
				mouseJointDef.timeStep=m_timeStep;
				mouseJoint=m_world.CreateJoint(mouseJointDef) as b2MouseJoint;
			}
		}
		public function destroyMouse(evt:MouseEvent):void {
			if (mouseJoint) {
				m_world.DestroyJoint(mouseJoint);
				mouseJoint=null;
			}
		}
		public function GetBodyAtMouse(includeStatic:Boolean=false):b2Body {
			var mouseXWorldPhys = (mouseX)/30;
			var mouseYWorldPhys = (mouseY)/30;
			mousePVec.Set(mouseXWorldPhys, mouseYWorldPhys);
			var aabb:b2AABB = new b2AABB();
			aabb.lowerBound.Set(mouseXWorldPhys - 0.001, mouseYWorldPhys - 0.001);
			aabb.upperBound.Set(mouseXWorldPhys + 0.001, mouseYWorldPhys + 0.001);
			var k_maxCount:int=10;
			var shapes:Array = new Array();
			var count:int=m_world.Query(aabb,shapes,k_maxCount);
			var body:b2Body=null;
			for (var i:int = 0; i < count; ++i) {
				if (shapes[i].GetBody().IsStatic()==false||includeStatic) {
					var tShape:b2Shape=shapes[i] as b2Shape;
					var inside:Boolean=tShape.TestPoint(tShape.GetBody().GetXForm(),mousePVec);
					if (inside) {
						body=tShape.GetBody();
						break;
					}
				}
			}
			return body;
		}
		public function Update(e:Event):void {
			m_world.Step(m_timeStep, m_iterations);
			if (mouseJoint) {
				var mouseXWorldPhys=mouseX/30;
				var mouseYWorldPhys=mouseY/30;
				var p2:b2Vec2=new b2Vec2(mouseXWorldPhys,mouseYWorldPhys);
				mouseJoint.SetTarget(p2);
			}
		}
		public var m_world:b2World;
		public var m_iterations:int=10;
		public var m_timeStep:Number=1.0/30.0;
	}
}

Line 16: Declaration of the_rev_joint variable, a b2RevoluteJointDef type

Lines 40-46: Creating a circle in the middle of the stage that will act as a pivot point. In most examples around the web you will find pivot points as tiny, almost invisible boxes. I am making a big one because I think it will be easier to skin it once I will need to do it. Notice at line 41 that the object is static because it has density at zero.

Lines 48-56: Creation of the box that will be tied to the joint. You can virtually place it anywhere, but for an interesting result, it should be in a position where the joint can act as a fulcrum.

Line 57: Initializing the joint: I am passing the joint pivot, the body tied to the joint and the point of intersection. You can see the (8.5,6.5) is the same as pivot's origin (line 43).

Line 58: Adding the joint to the world.

And that's it. Believe me, Box2D is very easy once you know the basics.

And this is the source code for you to download.