Emanuele Feronato

Talking about Bloons game, Flash and Game development.

One of the moust famous Flash games ever is Bloons.

Please, don’t make me explain what I am talking about. Just play it. I really do not know why nobody tried to make a clone of such a simple game. Then I realized… that’s because I never published a prototype of this game.

Now, it’s time for me to give you the tools to flood the net with a million Bloons clones!

The prototype is heavily based on Create a flash artillery game – step 1, and I strongly recommend you to read it.

Then, here it is the source code, that will be commented once I will release a complete level

Mouse.hide();
level = new Array();
level[0] = new Array(1, 1, 1, 1, 1, 1, 1);
level[1] = new Array(1, 0, 1, 1, 1, 0, 1);
level[2] = new Array(1, 1, 1, 1, 1, 1, 1);
level[3] = new Array(1, 1, 1, 0, 1, 1, 1);
level[4] = new Array(1, 1, 1, 1, 1, 1, 1);
level[5] = new Array(1, 0, 1, 1, 1, 0, 1);
level[6] = new Array(1, 1, 1, 1, 1, 1, 1);
for (y=0; y<=6; y++) {
	for (x=0; x<=6; x++) {
		if (level[y][x] == 1) {
			the_bloon = _root.attachMovie("bloon", "bloon"+_root.getNextHighestDepth(), _root.getNextHighestDepth(), {_x:x*35+125, _y:y*35+20});
			the_bloon.gotoAndStop(Math.floor(Math.random()*6+1));
			the_bloon.onEnterFrame = function() {
				spike_x = cannonball._x+20*Math.cos(cannonball._rotation/180*Math.PI)
				spike_y = cannonball._y+20*Math.sin(cannonball._rotation/180*Math.PI)
				if (this.hitTest(spike_x, spike_y, true)) {
					this.removeMovieClip();
				}
			}
		}
	}
}
gravity = 2;
firing = 0;
firepower = 0;
fire_increment = 1;
bullet_in_air = false;
attachMovie("crosshair","crosshair",_root.getNextHighestDepth());
attachMovie("tank","tank",_root.getNextHighestDepth(),{_x:230, _y:350});
crosshair.onEnterFrame = function() {
	this._x = _xmouse;
	this._y = _ymouse;
};
tank.onEnterFrame = function() {
	mousex = _xmouse-this._x;
	mousey = (_ymouse-this._y)*-1;
	angle = Math.atan2(mousey, mousex);
	this.cannon._rotation = -angle*180/Math.PI;
	if (firing) {
		if ((firepower>50) or (firepower<0)) {
			fire_increment *= -1;
		}
		firepower += fire_increment;
		this.cannon.powermeter._width += fire_increment;
	}
};
function onMouseDown() {
	if ((!firing) and (!bullet_in_air)) {
		firing = true;
	}
}

function onMouseUp() {
	if (firing) {
		firing = false;
		tank.cannon.powermeter._width = 40;
		fire_increment = 1;
		angle = tank.cannon._rotation;
		start_ball_x = tank._x+48*Math.cos(angle*Math.PI/180);
		start_ball_y = tank._y+48*Math.sin(angle*Math.PI/180);
		cannonball_fired = attachMovie("cannonball", "cannonball", 10000, {_x:start_ball_x, _y:start_ball_y});
		cannonball_fired.dirx = Math.cos(angle*Math.PI/180)*firepower;
		cannonball_fired.diry = Math.sin(angle*Math.PI/180)*firepower;
		bullet_in_air = true;
		cannonball_fired.onEnterFrame = function() {
			this.diry += gravity;
			this._x += this.dirx/2;
			this._y += this.diry/2;
			this._rotation = Math.atan2(this.diry, this.dirx)*180/Math.PI;
			if (this._y>400) {
				bullet_in_air = false;
				this.removeMovieClip();
			}
		};
		firepower = 0;
	}
}

And here it is the result:

Enjoy!!!! And download the source!!