Emanuele Feronato

Talking about Actionscript 3, Flash and Game development.

In AS3 Flash game creation tutorial – part 3: walls I introduce some obstacles to kill the circle, now it’s time to make it earn some points when it collects the coins.

As usual, I am creating a new movieclip called score with its score.as class.

This is how score.as looks like:

package {
	import flash.display.Sprite;
	// look! you need text.TextField in order to make it work
	import flash.text.TextField;
	public class score extends Sprite {
		public function score() {
			// this.scoretext.text = "0" works
			// this.scoretext.text = 0; does not work
			this.scoretext.text = String(0);
		}
		public function updatescore(score) {
			// updating the score
			this.scoretext.text = String(score);
		}
	}
}

Look at line 4… I need to import text.TextField in order to have text fields to work (it was “native” under AS2) and at line 9 you will find you have to convert a number to a string before displaying it in the text field (you did not need to do that in AS2).

Apart from this, there is nothing interesting in the score class, but it’s more interesting how other classes call it.

This is the new coin.as

package {
	import flash.display.Sprite;
	import flash.events.Event;
	public class coin extends Sprite {
		// variables used in this class
		private var dist_x:int;
		private var dist_y:int;
		private var distance:int;
		// main function
		public function coin() {
			// calling place_coin function.
			// this function randomly places the coin in the field
			place_coin();
			// checking for collisions at every frame
			addEventListener(Event.ENTER_FRAME, check_collisions);
		}
		private function check_collisions(e:Event) {
			// determining the distance between the hero and the coin
			// notice how do I refer the hero
			dist_x = x - as3circle(root).circle_hero.x;
			dist_y = y - as3circle(root).circle_hero.y;
			distance = dist_x*dist_x+dist_y*dist_y;
			// 1809 = (hero radius + coin radius)^2
			// this way I don't have to perform a square root to distance
			if (distance < 1089) {
				// if the hero picks up a coin, then move it elsewhere
				as3circle(root).add_score(1);
				place_coin();
			}
		}
		private function place_coin() {
			x = Math.floor(Math.random()*400)+50;
			y = Math.floor(Math.random()*300)+50;
		}
	}
}

Look at line 27 how I am calling the add_score function adding one point for every coin collected. Where is the add_score function?

It's on the main class, as3circle.as

package {
	import flash.display.Sprite;
	import flash.events.Event;
	public class as3circle extends Sprite {
		public var keyboard_input:keys;
		public var circle_hero = new circle;
		public var your_score = new score;
		public var level_wall = new wall;
		public var my_score = 0;
		public var number_of_coins = 4;
		public function as3circle() {
			for (var i=1; i<=number_of_coins; i++) {
				var ingame_coin = new coin;
				addChild(ingame_coin);
			}
			addChild(your_score);
			addChild(circle_hero);
			var keyboard_sprite = new Sprite();
			keyboard_input = new keys(this);
			addChild(level_wall);
			stage.addEventListener(Event.ENTER_FRAME,on_enter_frame);
		}
		public function on_enter_frame(event:Event) {
			if (keyboard_input.is_left()) {
				circle_hero.apply_force(-1,0);
			}
			if (keyboard_input.is_right()) {
				circle_hero.apply_force(1,0);
			}
			if (keyboard_input.is_up()) {
				circle_hero.apply_force(0,-1);
			}
			if (keyboard_input.is_down()) {
				circle_hero.apply_force(0,1);
			}
		}
		public function add_score(points) {
			my_score += points;
			your_score.updatescore(my_score);
		}
	}
}

First, at line 7 I create a score variable called your_score, then I add it to the stage at line 16, and the function that adds the score is at lines 37-40.

While I am using the score movieclip only to display the score, I am saving it in the main class thanks to my_score variable declared at line 9.

Then, add_score updates the score at line 38 and calls the function to show the updated score on screen at line 39.

Small recap: coin.as calls a function in as3circle.as that updates the score and calls score.as to write the updated score.

The other classes remain the same, and this is the result:

Download the source code. In next step, I will turn this game into a real one...