Emanuele Feronato

Talking about Actionscript 3 and Flash.

The Plane is the simplest object you can create with Papervision3D.

But “simple” does not mean we don’t have a set of options to custom our planes.

Look at this script, that is quite the same as the one published at Papervision3D for the absolute beginners:

package {
	import flash.display.Sprite;
	import flash.events.Event;
	import org.papervision3d.cameras.Camera3D;
	import org.papervision3d.render.BasicRenderEngine;
	import org.papervision3d.scenes.Scene3D;
	import org.papervision3d.view.Viewport3D;
	import org.papervision3d.objects.primitives.Plane;
	public class papervision extends Sprite {
		public var viewport:Viewport3D = new Viewport3D();
		public var scene:Scene3D = new Scene3D();
		public var camera:Camera3D = new Camera3D();
		public var renderer:BasicRenderEngine = new BasicRenderEngine();
		public var plane:Plane = new Plane();
		public function papervision() {
			addChild(viewport);
			scene.addChild(plane);
			addEventListener(Event.ENTER_FRAME, render);
		}
		public function render(e:Event) {
			plane.pitch(1);
			renderer.renderScene(scene, camera, viewport);
		}
	}
}

The only changes are I added an ENTER_FRAME listener to render the scene at every frame because renderScene renders the scene only once, and I added a pitch method to the plane to make it rotate along its x axis by 1 degree at every frame.

Let’s look at the movie:

If you notice, when the plane rotates over 180 degrees, it disappears. By default, planes aren’t double sided.

To create a double sided plane, we’ll need to define a material and set this material as double sided.

package {
	import flash.display.Sprite;
	import flash.events.Event;
	import org.papervision3d.cameras.Camera3D;
	import org.papervision3d.render.BasicRenderEngine;
	import org.papervision3d.scenes.Scene3D;
	import org.papervision3d.view.Viewport3D;
	import org.papervision3d.objects.primitives.Plane;
	import org.papervision3d.materials.WireframeMaterial;
	public class papervision extends Sprite {
		public var viewport:Viewport3D = new Viewport3D();
		public var scene:Scene3D = new Scene3D();
		public var camera:Camera3D = new Camera3D();
		public var renderer:BasicRenderEngine = new BasicRenderEngine();
		public var wireframe:WireframeMaterial = new WireframeMaterial();
		public var plane:Plane= new Plane(wireframe);
		public function papervision() {
			addChild(viewport);
			wireframe.doubleSided = true;
			scene.addChild(plane);
			addEventListener(Event.ENTER_FRAME, render);
		}
		public function render(e:Event) {
			plane.pitch(1);
			renderer.renderScene(scene, camera, viewport);
		}
	}
}

Line 9: importing the wireframe material, the simplest one

Line 15: declaring the wireframe variable, WireframeMaterial type – in this example, it’s important you declare it before plane declaration

Line 16: when declaring the plane, now I am passing the material as a parameter. It’s not the only parameter I can pass, but at the moment that’s what I need

Line 19: Setting wireframe material as double sided

And now finally we have a double sided plane

Now let’s see the other parameters you can pass when creating a plane:

package {
	import flash.display.Sprite;
	import flash.events.Event;
	import org.papervision3d.cameras.Camera3D;
	import org.papervision3d.render.BasicRenderEngine;
	import org.papervision3d.scenes.Scene3D;
	import org.papervision3d.view.Viewport3D;
	import org.papervision3d.objects.primitives.Plane;
	import org.papervision3d.materials.WireframeMaterial;
	public class papervision extends Sprite {
		public var viewport:Viewport3D = new Viewport3D();
		public var scene:Scene3D = new Scene3D();
		public var camera:Camera3D = new Camera3D();
		public var renderer:BasicRenderEngine = new BasicRenderEngine();
		public var wireframe:WireframeMaterial = new WireframeMaterial();
		public var plane:Plane=new Plane(wireframe,500,750,4,5);
		public function papervision() {
			addChild(viewport);
			plane.rotationY=45;
			plane.x=-200;
			plane.y=100;
			wireframe.doubleSided=true;
			scene.addChild(plane);
			addEventListener(Event.ENTER_FRAME, render);
		}
		public function render(e:Event) {
			plane.pitch(1);
			renderer.renderScene(scene, camera, viewport);
		}
	}
}

Let’s look at plane’s declaration… it now has five parameters…

wireframe is the material as seen before

500 is the width of the plane. 500 pixels? 500 meters? At the moment let’s call them 500 units… I’ll explain in another tutorial how to manage units

750 represents the height

4 is the number of segments in the plane width. The more the segments, the more detailed the final render, the more the CPU will stress. It’s up to you playing carefully with this parameter.

5 represents the same thing for the plane height

Moreover, as you can see at lines 19-21, there are other parameters you can change to make the plane suits what you want, but I’ll explain them later, when we’ll see how Papervision3D manages units.

Here it is:

No downloads this time, just copy/paste one of the codes of this tutorial into the example you can download at Papervision3D for the absolute beginners.