Emanuele Feronato

Talking about Actionscript 2, Flash, Game development and Tutorials.

Now that you know how to communicate between two Flash movies thanks to the Creation of a Flash highscores API tutorial, it’s time to introduce the next step that will make you save your highest score on your computer.

It’s not an hard prototype once you read Create an Eskiv Flash game tutorial (in order to have a real game) and Managing savegames with Flash shared objects (to store data on your computer)

This is the game:

var send_score:LocalConnection = new LocalConnection();
_root.attachMovie("score", "score", 1);
_root.attachMovie("hero", "hero", 2, {_x:250, _y:200});
_root.attachMovie("target", "target", 3, {_x:Math.random()*400+25, _y:Math.random()*300+25});
enemy_power = 3;
points = 0;
max_score = 0;
hero.onEnterFrame = function() {
	this._x = _root._xmouse;
	this._y = _root._ymouse;
};
target.dir = Math.random()*2*Math.PI;
target.xspeed = enemy_power*Math.cos(foe.dir);
target.yspeed = enemy_power*Math.sin(foe.dir);
target.onEnterFrame = function() {
	dist_x = this._x-hero._x;
	dist_y = this._y-hero._y;
	distance = Math.sqrt(dist_x*dist_x+dist_y*dist_y);
	if (distance<(hero._width+this._width)/2) {
		points++;
		if (points>max_score) {
			max_score = points;
			send_score.send("hall_of_fame", "compare_scores", points);
		}
		score.scoretxt.text = points;
		this._x = Math.random()*400+25;
		this._y = Math.random()*300+25;
		foe = _root.attachMovie("enemy", "enemy", _root.getNextHighestDepth(), {_x:Math.random()*400+25, _y:Math.random()*300+25});
		foe.dir = Math.random()*2*Math.PI;
		foe.xspeed = enemy_power*Math.cos(foe.dir);
		foe.yspeed = enemy_power*Math.sin(foe.dir);
		foe.onEnterFrame = function() {
			this._x += this.xspeed;
			this._y += this.yspeed;
			if ((this._x<0) or (this._x>500)) {
				this.xspeed *= -1;
			}
			if ((this._y<0) or (this._y>400)) {
				this.yspeed *= -1;
			}
			dist_x = this._x-hero._x;
			dist_y = this._y-hero._y;
			distance = Math.sqrt(dist_x*dist_x+dist_y*dist_y);
			if (distance<(hero._width+this._width)/2) {
				points--;
				score.scoretxt.text = points;
				this.removeMovieClip();
			}
		};
	}
};

The game game developer only needs to add line 1 and line 23 to his game

and this is the highscore table

var get_score:LocalConnection = new LocalConnection();
get_score.connect("hall_of_fame");
top_score = SharedObject.getLocal("feronato");
if (top_score.data.score == undefined) {
	top_score.data.score = 0;
}
_root.topscore.text = "Highest score: "+top_score.data.score;
get_score.compare_scores = function(points):Void  {
	if (points>top_score.data.score) {
		top_score.data.score = points;
	}
	_root.currentscore.text = "Score: "+points;
	_root.topscore.text = "Highest score: "+top_score.data.score;
};

Now play the game here, move the purple circle with the mouse, pick up the red circle, avoid the blue ones.

and see your best performance here.

Even if you reload, or close the page and open it again.

I noticed sometimes I need to reload the page in order to make it works. Does it happen to you too?

Having a complete online leaderboard is a long journey, but we'll have it soon

Meanwhile, download the source codes and experiment